精华区文章阅读

发信人: bloom (又臭又硬小石头), 信区: VB
标  题: 屏蔽文本框默认的右键菜单�
发信站: 哈工大紫丁香 (2000年07月19日13:03:35 星期三), 转信

    屏蔽文本框的右键菜单，曾经看到一个程序是这样做的：
    Private Sub Text1_MouseDown(Button As Integer, Shift As Integer, X As Si
ngle, Y As Single)
        Text1.Enabled = False
        Text1.Enabled = True
        PopupMenu yourmenu
    End Sub
    这当然是个简单的实现方法，但作为一个以api为主题的网站，我在此想介绍一种用
api函数来实现的方法，并想谈的深入一些。
    首先，谈谈消息和窗口函数。在Windows里，消息有两方面的用途：首先，它们由W
indows传给窗口函数，指出发生了一个特定的事件。比如用户单击了鼠标，或者按下了
键盘上的某个键。消息也可由Windows用于通告发生了一个内部事件，比如输入焦点的变
更。另外，可将消息作为Windows的一种命令使用。这种命令用于通知一个窗口执行特定
的任务。其次，通常可将消息传给一个控件或窗口，请求它执行特定的操作。而每个窗
口都有一个窗口函数，它的作用是对消息进行处理。该函数就象一个特殊的VB程序，其
中包含了对事件进行处理的代码。
    对于右击文本框，首先是产生一条 WM_CONTEXTMENU 消息，该消息被文本框的窗口
函数接收，就会弹出默认的菜单。所以，我的思路是：接收所有的文本框消息，如果消
息为 WM_CONTEXTMENU ，那么弹出自定义菜单，否则，把消息传递给默认的窗口函数由
它处理。
    如何接收消息？一个方法是，用 AddressOf 关键字，它可以把一个自定义模块的地
址变为窗口函数的地址。这样，窗口函数就成了你的自定义模块了。而消息仍然传递到
原先窗口函数的地址（这时，这个地址指向的窗口函数已经是你的自定义模块）
    现在就看看是如何实现的吧。首先建议你看看VB联机手册关于 AddressOf 的帮助。
程序需要一个窗体、窗体中有一个文本框，以及一个标准模块。
    标准模块的代码：
    Option Explicit
    Public OldWindowProc As Long
    ' 保存默认的窗口函数的地址
    Public Const WM_CONTEXTMENU = &H7B
    ' 当右击文本框时，产生这条消息
    Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA
" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
    Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA
" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Lon
g
    Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowPr
ocA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, By
Val wParam As Long, ByVal lParam As Long) As Long
    Public Function SubClass1_WndMessage(ByVal hWnd As OLE_HANDLE, ByVal Msg
As OLE_HANDLE, ByVal wp As OLE_HANDLE, ByVal lp As Long) As Long
        If Msg <> WM_CONTEXTMENU Then
            SubClass1_WndMessage = CallWindowProc(OldWindowProc, hWnd, Msg,
wp, lp)
            ' 如果消息不是WM_CONTEXTMENU，就调用默认的窗口函数处理
            Exit Function
        End If
        SubClass1_WndMessage = True
    End Function
    窗体的代码：
    Option Explicit
    Private Const GWL_WNDPROC = (-4)
    Private Sub Text1_MouseDown(Button As Integer, Shift As Integer, X As Si
ngle, Y As Single)
        If Button = 1 Then Exit Sub
        OldWindowProc = GetWindowLong(Text1.hWnd, GWL_WNDPROC)
        ' 取得窗口函数的地址
        Call SetWindowLong(Text1.hWnd, GWL_WNDPROC, AddressOf SubClass1_WndM
essage)
        ' 用SubClass1_WndMessage代替窗口函数处理消息
    End Sub
    Private Sub Text1_MouseUp(Button As Integer, Shift As Integer, X As Sing
le, Y As Single)
        If Button = 1 Then Exit Sub
        Call SetWindowLong(Text1.hWnd, GWL_WNDPROC, OldWindowProc)
        ' 恢复窗口的默认函数
        PopupMenu usermenu
        ' 弹出自定义菜单
    End Sub
    运行这个程序，右键菜单已被自定义菜单取代，不会出现两个菜单的情况。关于这
个程序，你可以在例程中下载它，实现的功能比这里的要完整。最后要说明的是，尽量
不要使用 AddressOf 来改变一个窗口的默认窗口函数，它可能引起不可预料的后果。在
VB的联机手册里也是这样建议的，我在编这个程序时，死过几次机，其中一次，搞的我
的Windows的“开始”菜单没有反应。
    在Windows 98 + VB5.0下通过。本文涉及的api函数本站有介绍。

--
※ 来源:·哈工大紫丁香 bbs.hit.edu.cn·[FROM: 202.118.233.140]
--
※ 修改:·bloom 於 07月19日13:03:56  修改本文·[FROM: jxjdadmin.hit.edu.cn]
※ 转载:．哈工大紫丁香 bbs.hit.edu.cn．[FROM: jxjdadmin.hit.edu.cn]

VB 版 (精华区)