精华区文章阅读

发信人: student (earth), 信区: VB
标  题: 如何使用 NetRemoteTOD 来从服务器获取 Date 和时间�
发信站: 哈工大紫丁香 (2001年11月25日19:17:50 星期天), 站内信件

本文信息适用于:
Microsoft Visual FoxPro for Windows, version 6.0 :
Microsoft Windows NT 4.0
Microsoft Windows 2000 4.0
概述
在 Microsoft Windows NT 4.0 或 Microsoft Windows 2000 中, 可以象下面一样用 N
ET 命令来获取服务器的日期和时间:
NET TIME \\ServerName
要避免外壳程序的新处理的系统开销, 可以在 Windows NT 下以编程方式用 NetRemote
TOD API 函数获取这些信息.
更多信息
注意: 在 Windows 2000 终端服务程序下这些代码在 Visual FoxPro 中不能工作.
保存并运行以下代码, 在以下行中指定你想查询时间的服务器名:
server_name = "yourservername"
* NetRemoteTOD 的第一个参数是一个指向包含服务器名的
* Unicode 串的指针.
*
* 第二个参数是指向包含一个指向 TIME_OF_DAY_INFO 结构的指针的一个字节数组的指
针(太拗口了,原文见下)
* a pointer to a byte array containing a pointer to a TIME_OF_DAY_INFO struc
ture
* 第二个参数的 '@' 前缀 ('integer @')
* 表明该参数按址传递. 在程序的稍后,
* 程序使用 RTLMoveMemory() 来获取这个指向字节数组的指针的内容
DECLARE INTEGER NetRemoteTOD IN netapi32 STRING @,  INTEGER @
* 注意源地址 ('inbuffer') 定义为 integer,
* 与上面的 NetRemoteTOD 的第二个参数一致.
DECLARE INTEGER RtlMoveMemory IN win32api ;
   STRING @outbuffer, ;
   INTEGER inbuffer, ;
   INTEGER bytes2copy
* TIME_OF_DAY_INFO 结构包括
* 11 个 DWORD 和 1 个 long,
* 共 48 字节, 因此 tdbuffout
* 初始化为:
tdbuffout=REPLICATE(CHR(0), 48)
tdbuffin = 0
* 服务器名必须转换为 Unicode
* 该 API 函数行为的差异取决于
* 目标计算机是不是一个 Win2000 机器 -
*
* 如果是 Win2000, 则服务器名必须前面有 "\\";
* 否则, 就不能有.
server_name = "yourservername"
try_server_name = STRCONV(server_name, 5)
rc = NetRemoteTOD(@try_server_name, @tdbuffin)
IF rc = 0
   * 复制 tdbuffin 所指向的地址中的内容到 tdbuffout
   =RtlMoveMemory(@tdbuffout, tdbuffin, 48)
ELSE
   * 调用失败, 因此目标可能是一个 Win2000 框;
   * 重试函数调用, 添加前缀 "\\" 到 server_name
   try_server_name = STRCONV("\\" + server_name, 5)
   rc = NetRemoteTOD(@try_server_name, @tdbuffin)
   IF rc = 0
      * 复制 tdbuffin 所指向的地址中的内容到 tdbuffout
      =RtlMoveMemory(@tdbuffout, tdbuffin, 48)
   ELSE
      ? "NetRemoteTOD() call failed. Return code is: ", rc
      RETURN
   ENDIF
ENDIF
* 拾取出 TIME_OF_DAY_INFORMATION 缓存中的适当部分.
* 该缓存将包含有服务器的 UTC (全球座标时间) of the server,
* 对于正确的本地时间,且必须调整到 TOD_TIMEZONE 分.
* str2long() 转换 DWORDS 和 LONGS 从串表示到数值.
tod_month = str2long(SUBSTR(tdbuffout, 37, 4))
tod_day = str2long(SUBSTR(tdbuffout, 33, 4))
tod_year = str2long(SUBSTR(tdbuffout, 41, 4))
tod_hours = str2long(SUBSTR(tdbuffout, 9, 4))
tod_mins = str2long(SUBSTR(tdbuffout, 13, 4))
tod_secs = str2long(SUBSTR(tdbuffout, 17, 4))
* 减去这个基线 (乘以 60, 获得秒数)
* 来从 datetime 值来获得服务器的本地时间
*
* 可选地, 要转换服务器的本地时间到工作站的本地时间, 使用 Win32 API 函数
* SystemTimeToTzSpecificLocalTime, 该函数仅可用于 Windows NT.
tod_timezone = str2long(SUBSTR(tdbuffout, 25, 4)) * 60
serverdatetime = DATETIME(tod_year, tod_month, tod_day, ;
   tod_hours, tod_mins, tod_secs)
? "UTC time of server is: ", serverdatetime
? "Server's local time is: ", serverdatetime - tod_timezone
*************************************************************
FUNCTION str2long
*************************************************************
* 参数: 低高 ASCII 格式的 4 字节字符串 (m.longstr)
* 返回: 长整型值
* 示例:
* m.longstr = "1111"
* m.longval = str2long(m.longstr)
PARAMETERS m.longstr
PRIVATE i, m.retval
m.retval = 0
FOR i = 0 TO 24 STEP 8
   m.retval = m.retval + (ASC(m.longstr) * (2^i))
   m.longstr = RIGHT(m.longstr, LEN(m.longstr) - 1)
NEXT
RETURN m.retval
远程 UTC 时间和服务器的本地时间出现在 Visual FoxPro 桌面上.
参考
MSDN 中的 "NetRemoteTOD" 和 "RTLMovememory" 主题

--
※ 来源:·哈工大紫丁香 bbs.hit.edu.cn·[FROM: 202.118.236.168]

VB 版 (精华区)